Класс для работы с SQL запросами.

Делу время, а потехе час. Это я к тому, что помимо исследований Delphi для Android (а вы уже тестируете бету?) есть работа, которую нужно делать.  За сим, очередной пост-шпаргалка, возможно, кому-нибудь пригодится.

В коде моих проектов имеется множество функций, подобных, приведенной ниже.

function TFMain.ExtDescrExists(): Boolean;
var
 qry: TADOQuery;
begin
 Result:= True;
 try
 qry:= TADOQuery.Create(Self);
 qry.Connection:= DM.cnDatabase;
 qry.SQL.Add('SELECT ExpenseID FROM tblProjectExpenses WHERE ExpenseDescription<>NULL');

 qry.Open;
 if qry.IsEmpty then
 begin
  Result:= False;
 end;
 qry.Close;
 finally
 FreeAndNil(qry);
 end;

end;

Откровенно говоря, подобный код мне не особо нравится, прежде всего из-за громоздкости. Обратите внимание на рисунок:

Необходимость повторного использования кода в данном случае очевидна. Однако, сделать универсальное решение не совсем просто, поскольку в некоторых случаях проверяется наличие записей в таблице, в других – требуется извлечь значения различных типов. Чтобы решить эту задачу, я набросал небольшой класс:

unit uATRQueries;

interface

uses
   ADODB, ADOInt, StrUtils, Dialogs,
  SysUtils, DB;
type
  TATRQuery = class
    strict private
     class var
     FConnection: TADOConnection;

    private
    class function GetDataBase: TADOConnection; static;
    class procedure SetDataBase(const Value: TADOConnection); static;

    public

    class function ExecSQL(aSQL: string): Boolean;
    class function GetRecCountBySQL(aSQL: string): integer;
    class function FieldValIsNULL(aSQL, aFieldName: string): Boolean;
    class function GetIntFieldBySQLDef(aSQL, aFieldName: string; def: Integer = 0;
        ShowEmptyMessage: Boolean = False; EmptyMessage: string = 'There are no records.'): integer;

    class function GetDataSet(aSQL: string): TDataSet;
    class property DataBase: TADOConnection read GetDataBase write SetDataBase;

  end;

implementation

uses
  uDM;

{ TATRQuery }

class function TATRQuery.GetDataBase: TADOConnection;
begin
 Result:= FConnection;
end;

class function TATRQuery.GetDataSet(aSQL: string): TDataSet;
var
Qry: TADOQuery;
begin
try
   Qry:= TADOQuery.Create(DM);
   qry.Connection:= FConnection;

   qry.SQL.Add(aSQL);
   qry.Open;

   Result:= qry as TDataSet;
finally

end;
end;

class function TATRQuery.GetIntFieldBySQLDef(aSQL, aFieldName: string;
  def: Integer; ShowEmptyMessage: Boolean; EmptyMessage: string): integer;
var
Qry: TADOQuery;

begin
 try
   Result:= Def;
   Qry:= TADOQuery.Create(DM);
   qry.Connection:= FConnection;

   qry.SQL.Add(aSQL);
   qry.Open;

   if Qry.IsEmpty then
   begin
   if ShowEmptyMessage then
    MessageDlg(EmptyMessage, mtWarning, [mbOK], 0);

    Exit;
   end;

   Result:= Qry.FieldByName(aFieldName).AsInteger;

 finally
   FreeAndNil(Qry);
 end;

end;

class function TATRQuery.GetRecCountBySQL(aSQL: string): integer;
var
Qry: TADOQuery;
begin
 try
   Result:= -1;
   Qry:= TADOQuery.Create(DM);
   qry.Connection:= FConnection;

   qry.SQL.Add(aSQL);
   qry.Open;
   Result:= qry.RecordCount;
 finally
   FreeAndNil(Qry);
 end;
end;

class function TATRQuery.ExecSQL(aSQL: string): Boolean;
  var
    Qry: TADOQuery;
begin
   Result:= True;
   try
     Qry:= TADOQuery.Create(DM);
     qry.Connection:= FConnection;
     qry.SQL.Add(aSQL);
     try
       qry.ExecSQL;
     except
       Result:= False;
     end;
   finally
    FreeAndNil(Qry);
   end;
end;

class function TATRQuery.FieldValIsNULL(aSQL, aFieldName: string): Boolean;
var
Qry: TADOQuery;
begin
 try
   Result:= False;
   Qry:= TADOQuery.Create(DM);
   qry.Connection:= FConnection;

   qry.SQL.Add(aSQL);
   qry.Open;
   Result:= Qry.FieldByName(aFieldName).IsNull;
 finally
   FreeAndNil(Qry);
 end

end;

class procedure TATRQuery.SetDataBase(const Value: TADOConnection);
begin
 if Assigned(Value) then
  FConnection:= Value;
end;

end.

Практически все методы, являются методами класса. Соответственно, использовать класс можно примерно так:

 TATRQuery.DataBase:= DM.cnDatabase;
 NeedCompany:=
  TATRQuery.FieldValIsNULL('SELECT dCompanyID FROM tblEmployees WHERE EmployeeID = '+IntToStr(aEmployeeID) , 'dCompanyID');

Как говорится, почувствуйте разницу!

Естественно, по мере необходимости функциональность класса может расширяться.